summarylogtreecommitdiffstats
path: root/PKGBUILD
diff options
context:
space:
mode:
authorSainnhepark2020-07-28 11:28:54 +0800
committerSainnhepark2020-07-28 11:28:54 +0800
commit5cc0a82c0d97ada563ca9a7ef8d83d971067e7c8 (patch)
tree9f2f6282d8cc48801b21c43dad4341da4fdd4cba /PKGBUILD
downloadaur-5cc0a82c0d97ada563ca9a7ef8d83d971067e7c8.tar.gz
init
Diffstat (limited to 'PKGBUILD')
-rw-r--r--PKGBUILD42
1 files changed, 42 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 00000000000..c275facd95d
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: Sainnhe Park <sainnhe@gmail.com>
+pkgname=vim-visual-multi-git
+_pkgname=vim-visual-multi
+pkgver=v0.5.4.r11.gf317dca
+pkgrel=1
+pkgdesc='Multiple cursors plugin for vim/neovim'
+arch=('any')
+url='https://github.com/mg979/vim-visual-multi'
+license=('MIT')
+depends=('vim')
+makedepends=('git')
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+install="${pkgname}.install"
+source=("${_pkgname}::git+${url}.git#branch=master"
+ "${pkgname}.install"
+ 'vimtutor-visual-multi'
+ 'visual-multi-vim-doc.hook')
+sha256sums=('SKIP'
+ '10e9f3d21e7f5fce07f2e8ffab0ccd08cdb52f5097c84afaa355c06668faf046'
+ '04d22ed7476c8c4ba565a805c8a3bac6e7252f6cc15106545e5c71dbb996229b'
+ 'cfdbc5aaa42b088365a4b99478a3efb56ab828a50e70e122f307ea2b8c3690bf')
+
+pkgver() {
+ cd "${srcdir}/${_pkgname}"
+ git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+ cd "${srcdir}/${_pkgname}"
+ touch doc/tags
+}
+
+package() {
+ cd "${srcdir}/${_pkgname}"
+ find autoload doc plugin python tutorialrc -type f -exec \
+ install -Dm 644 '{}' "${pkgdir}/usr/share/vim/vimfiles/pack/${_pkgname}/start/${_pkgname}/{}" \;
+ install -Dm 644 "${srcdir}/${_pkgname}/LICENSE" \
+ "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+ install -Dm 644 "${srcdir}"/visual-multi-vim-doc.hook "${pkgdir}"/usr/share/libalpm/hooks/visual-multi-vim-doc.hook
+ install -Dm 755 "${srcdir}"/vimtutor-visual-multi "${pkgdir}"/usr/bin/vimtutor-visual-multi
+}