summarylogtreecommitdiffstats
path: root/PKGBUILD
diff options
context:
space:
mode:
authorJ5lx2015-06-09 16:42:25 +0200
committerJ5lx2015-06-09 16:42:25 +0200
commit2041a92ca0d7517fa8729f5a1bb8c31b8d71c694 (patch)
tree0b071dc630a844ab4b4278fa7f0c2c35b81fca56 /PKGBUILD
downloadaur-clouseau-git.tar.gz
Initial import
Diffstat (limited to 'PKGBUILD')
-rw-r--r--PKGBUILD49
1 files changed, 49 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 00000000000..feadc76ae98
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: Doug Newgard <scimmia22 at outlook dot com>
+# Contributor: Leif Middelschulte <leif dot middelschulte at gmail dot com>
+
+_pkgname=clouseau
+pkgname=$_pkgname-git
+pkgver=0.2.1.r5.ga99981b
+pkgrel=1
+pkgdesc="Evas/Edje (EFL) introspection utility - Development version"
+arch=('i686' 'x86_64')
+url="http://www.enlightenment.org"
+license=('BSD')
+depends=('elementary>=1.10.99')
+makedepends=('git')
+provides=("$_pkgname=$pkgver")
+conflicts=("$_pkgname")
+source=("git://git.enlightenment.org/tools/$_pkgname.git")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd "$srcdir/$_pkgname"
+
+ git describe --tags --long | sed 's/^v//;s/-/.r/;s/-/./g'
+}
+
+build() {
+ cd "$srcdir/$_pkgname"
+
+ export CFLAGS="$CFLAGS -fvisibility=hidden"
+
+ ./autogen.sh \
+ --prefix=/usr \
+ --disable-static
+
+ make
+}
+
+package() {
+ cd "$srcdir/$_pkgname"
+
+ make DESTDIR="$pkgdir" install
+
+# install text files
+ install -d "$pkgdir/usr/share/doc/$_pkgname/"
+ install -m644 -t "$pkgdir/usr/share/doc/$_pkgname/" ChangeLog NEWS README
+
+# install license files
+ install -d "$pkgdir/usr/share/licenses/$pkgname/"
+ install -m644 -t "$pkgdir/usr/share/licenses/$pkgname/" AUTHORS COPYING COPYING.icons
+}