summarylogtreecommitdiffstats
diff options
context:
space:
mode:
authortinywrkb2020-08-04 23:05:36 +0300
committertinywrkb2020-08-04 23:05:36 +0300
commitae56d5cc997c7f391abda1be6673a19903c338af (patch)
treeebfbdb3a66295c185ff143de988bad1e8278bb7e
downloadaur-ae56d5cc997c7f391abda1be6673a19903c338af.tar.gz
initial import
-rw-r--r--.SRCINFO26
-rw-r--r--PKGBUILD56
2 files changed, 82 insertions, 0 deletions
diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 00000000000..c15de34b5dc
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,26 @@
+pkgbase = rofi-lbonn-wayland-git
+ pkgdesc = A window switcher, application launcher and dmenu replacement (Wayland fork)
+ pkgver = 1.3.1.r1315.g498fd2fc
+ pkgrel = 1
+ url = https://github.com/lbonn/rofi
+ arch = x86_64
+ license = MIT
+ makedepends = check
+ makedepends = git
+ makedepends = meson
+ makedepends = wayland-protocols
+ depends = libxdg-basedir
+ depends = startup-notification
+ depends = libxkbcommon-x11
+ depends = xcb-util-wm
+ depends = xcb-util-xrm
+ depends = librsvg
+ depends = wayland
+ optdepends = i3-wm: use as a window switcher
+ provides = rofi
+ conflicts = rofi
+ source = rofi::git+https://github.com/lbonn/rofi.git
+ sha256sums = SKIP
+
+pkgname = rofi-lbonn-wayland-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 00000000000..557a3615016
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,56 @@
+# Maintainer: tinywrkb <tinywrkb@gmail.com>
+# Contributor: Morten Linderud <foxboron@archlinux.org>
+# Contributor: Maxim Baz <rofi at maximbaz dot com>
+# Contributor: Anatol Pomozov
+# Contributor: Benjamin Chr├ętien <chretien + aur [at] lirmm [dot] fr>
+# Contributor: Eric Engestrom <aur [at] engestrom [dot] ch>
+# Contributor: Rasi <rasi@xssn.at>
+# Contributor: Sean Pringle <sean.pringle@gmail.com>
+# Contributor: SanskritFritz (gmail)
+
+_gitname=rofi
+pkgname=rofi-lbonn-wayland-git
+pkgver=1.3.1.r1315.g498fd2fc
+pkgrel=1
+pkgdesc='A window switcher, application launcher and dmenu replacement (Wayland fork)'
+arch=(x86_64)
+url="https://github.com/lbonn/$_gitname"
+license=(MIT)
+depends=(libxdg-basedir startup-notification libxkbcommon-x11 xcb-util-wm xcb-util-xrm librsvg wayland)
+makedepends=(check git meson wayland-protocols)
+optdepends=('i3-wm: use as a window switcher')
+provides=(rofi)
+conflicts=(rofi)
+source=("${_gitname}::git+${url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $_gitname
+ git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+ cd $_gitname
+ git submodule update --init
+}
+
+build() {
+ arch-meson \
+ -Dwayland=enabled \
+ -Dcheck=enabled \
+ $_gitname build
+ meson compile -C build
+}
+
+check() {
+ LC_ALL=C meson test -C build
+}
+
+package() {
+ DESTDIR="$pkgdir" meson install -C build
+
+ cd $_gitname
+ install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+ install -dm755 "$pkgdir/usr/share/doc/$_gitname/examples"
+ install -Dm755 Examples/*.sh "$pkgdir/usr/share/doc/$_gitname/examples"
+}