summarylogtreecommitdiffstats
diff options
context:
space:
mode:
authorzan2020-09-29 18:20:44 -0400
committerzan2020-09-29 18:20:44 -0400
commit3645d159d5938a00740c1117b4c0834ecbf99a45 (patch)
tree0289a418afb8bb158a5b5b3513e9b3b3ce6c459e
downloadaur-3645d159d5938a00740c1117b4c0834ecbf99a45.tar.gz
initial
-rw-r--r--.SRCINFO25
-rw-r--r--PKGBUILD42
-rwxr-xr-xajour.desktop8
3 files changed, 75 insertions, 0 deletions
diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 00000000000..b2204688b8c
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,25 @@
+pkgbase = ajour-git
+ pkgdesc = World of Warcraft addon manager written in Rust
+ pkgver = 0.3.4.r33.3dd767f
+ pkgrel = 1
+ url = https://www.getajour.com
+ arch = x86_64
+ license = MIT
+ makedepends = cargo
+ makedepends = rust
+ makedepends = icoutils
+ makedepends = git
+ depends = fontconfig
+ depends = freetype2
+ depends = hicolor-icon-theme
+ depends = libxcb
+ depends = openssl
+ provides = ajour
+ conflicts = ajour
+ source = git+https://github.com/casperstorm/ajour.git
+ source = ajour.desktop
+ sha256sums = SKIP
+ sha256sums = d356c0f7ab3087a087e2ff261bf6348e62e87190805fa166fcbe9e3f8b64fb0d
+
+pkgname = ajour-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 00000000000..e4e4a372588
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: zan <zan@420blaze.it>
+
+pkgname=ajour-git
+_name=${pkgname%-git}
+pkgver=0.3.4.r33.3dd767f
+pkgrel=1
+pkgdesc='World of Warcraft addon manager written in Rust'
+url='https://www.getajour.com'
+license=(MIT)
+arch=(x86_64)
+depends=(fontconfig freetype2 hicolor-icon-theme libxcb openssl)
+makedepends=(cargo rust icoutils git)
+conflicts=(ajour)
+provides=(ajour)
+source=("git+https://github.com/casperstorm/$_name.git"
+ "$_name.desktop")
+sha256sums=('SKIP'
+ 'd356c0f7ab3087a087e2ff261bf6348e62e87190805fa166fcbe9e3f8b64fb0d')
+
+pkgver() {
+ cd "$_name"
+ printf "%s" "$(git describe --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
+}
+
+build() {
+ cd "$_name"
+ cargo build --release
+ icotool "resources/windows/ajour.ico" -x
+}
+
+package() {
+ install -Dm644 "$_name.desktop" "$pkgdir/usr/share/applications/$_name.desktop"
+ cd "$_name"
+ install -Dm755 "target/release/$_name" "$pkgdir/usr/bin/$_name"
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+ for i in "1 16" "2 24" "3 32" "4 48" "5 256";
+ do
+ set -- $i
+ install -Dm644 "${_name}_$1_$2x$2x32.png" "$pkgdir/usr/share/icons/hicolor/$2x$2/apps/$_name.png"
+ done
+}
diff --git a/ajour.desktop b/ajour.desktop
new file mode 100755
index 00000000000..b73c1ca55f0
--- /dev/null
+++ b/ajour.desktop
@@ -0,0 +1,8 @@
+[Desktop Entry]
+Categories=Utility
+Comment=
+Exec=ajour
+GenericName=World of Warcraft Addon Manager
+Icon=ajour
+Name=Ajour
+Type=Application